01ff5fc7f7
commit 41a506ef71eb38d94fe133f565c87c3e06ccc072 upstream.
With ppc64 -mprofile-kernel and ppc32 -pg, profiling instructions to
call into ftrace are emitted right at function entry. The instruction
sequence used is minimal to reduce overhead. Crucially, a stackframe is
not created for the function being traced. This breaks stack unwinding
since the function being traced does not have a stackframe for itself.
As such, it never shows up in the backtrace:
/sys/kernel/debug/tracing # echo 1 > /proc/sys/kernel/stack_tracer_enabled
/sys/kernel/debug/tracing # cat stack_trace
Depth Size Location (17 entries)
----- ---- --------
0) 4144 32 ftrace_call+0x4/0x44
1) 4112 432 get_page_from_freelist+0x26c/0x1ad0
2) 3680 496 __alloc_pages+0x290/0x1280
3) 3184 336 __folio_alloc+0x34/0x90
4) 2848 176 vma_alloc_folio+0xd8/0x540
5) 2672 272 __handle_mm_fault+0x700/0x1cc0
6) 2400 208 handle_mm_fault+0xf0/0x3f0
7) 2192 80 ___do_page_fault+0x3e4/0xbe0
8) 2112 160 do_page_fault+0x30/0xc0
9) 1952 256 data_access_common_virt+0x210/0x220
10) 1696 400 0xc00000000f16b100
11) 1296 384 load_elf_binary+0x804/0x1b80
12) 912 208 bprm_execve+0x2d8/0x7e0
13) 704 64 do_execveat_common+0x1d0/0x2f0
14) 640 160 sys_execve+0x54/0x70
15) 480 64 system_call_exception+0x138/0x350
16) 416 416 system_call_common+0x160/0x2c4
Fix this by having ftrace create a dummy stackframe for the function
being traced. With this, backtraces now capture the function being
traced:
/sys/kernel/debug/tracing # cat stack_trace
Depth Size Location (17 entries)
----- ---- --------
0) 3888 32 _raw_spin_trylock+0x8/0x70
1) 3856 576 get_page_from_freelist+0x26c/0x1ad0
2) 3280 64 __alloc_pages+0x290/0x1280
3) 3216 336 __folio_alloc+0x34/0x90
4) 2880 176 vma_alloc_folio+0xd8/0x540
5) 2704 416 __handle_mm_fault+0x700/0x1cc0
6) 2288 96 handle_mm_fault+0xf0/0x3f0
7) 2192 48 ___do_page_fault+0x3e4/0xbe0
8) 2144 192 do_page_fault+0x30/0xc0
9) 1952 608 data_access_common_virt+0x210/0x220
10) 1344 16 0xc0000000334bbb50
11) 1328 416 load_elf_binary+0x804/0x1b80
12) 912 64 bprm_execve+0x2d8/0x7e0
13) 848 176 do_execveat_common+0x1d0/0x2f0
14) 672 192 sys_execve+0x54/0x70
15) 480 64 system_call_exception+0x138/0x350
16) 416 416 system_call_common+0x160/0x2c4
This results in two additional stores in the ftrace entry code, but
produces reliable backtraces.
Fixes: 153086644fd1 ("powerpc/ftrace: Add support for -mprofile-kernel ftrace ABI")
Cc: stable@vger.kernel.org
Signed-off-by: Naveen N Rao <naveen@kernel.org>
Signed-off-by: Michael Ellerman <mpe@ellerman.id.au>
Link: https://msgid.link/20230621051349.759567-1-naveen@kernel.org
Signed-off-by: Greg Kroah-Hartman <gregkh@linuxfoundation.org>
339 lines
7.4 KiB
ArmAsm
Executable file
339 lines
7.4 KiB
ArmAsm
Executable file
/* SPDX-License-Identifier: GPL-2.0-or-later */
|
|
/*
|
|
* Split from ftrace_64.S
|
|
*/
|
|
|
|
#include <linux/magic.h>
|
|
#include <asm/ppc_asm.h>
|
|
#include <asm/asm-offsets.h>
|
|
#include <asm/ftrace.h>
|
|
#include <asm/ppc-opcode.h>
|
|
#include <asm/export.h>
|
|
#include <asm/thread_info.h>
|
|
#include <asm/bug.h>
|
|
#include <asm/ptrace.h>
|
|
|
|
/*
|
|
*
|
|
* ftrace_caller()/ftrace_regs_caller() is the function that replaces _mcount()
|
|
* when ftrace is active.
|
|
*
|
|
* We arrive here after a function A calls function B, and we are the trace
|
|
* function for B. When we enter r1 points to A's stack frame, B has not yet
|
|
* had a chance to allocate one yet.
|
|
*
|
|
* Additionally r2 may point either to the TOC for A, or B, depending on
|
|
* whether B did a TOC setup sequence before calling us.
|
|
*
|
|
* On entry the LR points back to the _mcount() call site, and r0 holds the
|
|
* saved LR as it was on entry to B, ie. the original return address at the
|
|
* call site in A.
|
|
*
|
|
* Our job is to save the register state into a struct pt_regs (on the stack)
|
|
* and then arrange for the ftrace function to be called.
|
|
*/
|
|
_GLOBAL(ftrace_regs_caller)
|
|
/* Save the original return address in A's stack frame */
|
|
std r0,LRSAVE(r1)
|
|
|
|
/* Create a minimal stack frame for representing B */
|
|
stdu r1, -STACK_FRAME_MIN_SIZE(r1)
|
|
|
|
/* Create our stack frame + pt_regs */
|
|
stdu r1,-SWITCH_FRAME_SIZE(r1)
|
|
|
|
/* Save all gprs to pt_regs */
|
|
SAVE_GPR(0, r1)
|
|
SAVE_10GPRS(2, r1)
|
|
|
|
/* Ok to continue? */
|
|
lbz r3, PACA_FTRACE_ENABLED(r13)
|
|
cmpdi r3, 0
|
|
beq ftrace_no_trace
|
|
|
|
SAVE_10GPRS(12, r1)
|
|
SAVE_10GPRS(22, r1)
|
|
|
|
/* Save previous stack pointer (r1) */
|
|
addi r8, r1, SWITCH_FRAME_SIZE
|
|
std r8, GPR1(r1)
|
|
|
|
/* Load special regs for save below */
|
|
mfmsr r8
|
|
mfctr r9
|
|
mfxer r10
|
|
mfcr r11
|
|
|
|
/* Get the _mcount() call site out of LR */
|
|
mflr r7
|
|
/* Save it as pt_regs->nip */
|
|
std r7, _NIP(r1)
|
|
/* Also save it in B's stackframe header for proper unwind */
|
|
std r7, LRSAVE+SWITCH_FRAME_SIZE(r1)
|
|
/* Save the read LR in pt_regs->link */
|
|
std r0, _LINK(r1)
|
|
|
|
/* Save callee's TOC in the ABI compliant location */
|
|
std r2, 24(r1)
|
|
ld r2,PACATOC(r13) /* get kernel TOC in r2 */
|
|
|
|
addis r3,r2,function_trace_op@toc@ha
|
|
addi r3,r3,function_trace_op@toc@l
|
|
ld r5,0(r3)
|
|
|
|
#ifdef CONFIG_LIVEPATCH
|
|
mr r14,r7 /* remember old NIP */
|
|
#endif
|
|
/* Calculate ip from nip-4 into r3 for call below */
|
|
subi r3, r7, MCOUNT_INSN_SIZE
|
|
|
|
/* Put the original return address in r4 as parent_ip */
|
|
mr r4, r0
|
|
|
|
/* Save special regs */
|
|
std r8, _MSR(r1)
|
|
std r9, _CTR(r1)
|
|
std r10, _XER(r1)
|
|
std r11, _CCR(r1)
|
|
|
|
/* Load &pt_regs in r6 for call below */
|
|
addi r6, r1 ,STACK_FRAME_OVERHEAD
|
|
|
|
/* ftrace_call(r3, r4, r5, r6) */
|
|
.globl ftrace_regs_call
|
|
ftrace_regs_call:
|
|
bl ftrace_stub
|
|
nop
|
|
|
|
/* Load ctr with the possibly modified NIP */
|
|
ld r3, _NIP(r1)
|
|
mtctr r3
|
|
#ifdef CONFIG_LIVEPATCH
|
|
cmpd r14, r3 /* has NIP been altered? */
|
|
#endif
|
|
|
|
/* Restore gprs */
|
|
REST_GPR(0,r1)
|
|
REST_10GPRS(2,r1)
|
|
REST_10GPRS(12,r1)
|
|
REST_10GPRS(22,r1)
|
|
|
|
/* Restore possibly modified LR */
|
|
ld r0, _LINK(r1)
|
|
mtlr r0
|
|
|
|
/* Restore callee's TOC */
|
|
ld r2, 24(r1)
|
|
|
|
/* Pop our stack frame */
|
|
addi r1, r1, SWITCH_FRAME_SIZE+STACK_FRAME_MIN_SIZE
|
|
|
|
#ifdef CONFIG_LIVEPATCH
|
|
/* Based on the cmpd above, if the NIP was altered handle livepatch */
|
|
bne- livepatch_handler
|
|
#endif
|
|
|
|
ftrace_caller_common:
|
|
#ifdef CONFIG_FUNCTION_GRAPH_TRACER
|
|
.globl ftrace_graph_call
|
|
ftrace_graph_call:
|
|
b ftrace_graph_stub
|
|
_GLOBAL(ftrace_graph_stub)
|
|
#endif
|
|
|
|
bctr /* jump after _mcount site */
|
|
|
|
_GLOBAL(ftrace_stub)
|
|
blr
|
|
|
|
ftrace_no_trace:
|
|
mflr r3
|
|
mtctr r3
|
|
REST_GPR(3, r1)
|
|
addi r1, r1, SWITCH_FRAME_SIZE
|
|
mtlr r0
|
|
bctr
|
|
|
|
_GLOBAL(ftrace_caller)
|
|
/* Save the original return address in A's stack frame */
|
|
std r0, LRSAVE(r1)
|
|
|
|
/* Create a minimal stack frame for representing B */
|
|
stdu r1, -STACK_FRAME_MIN_SIZE(r1)
|
|
|
|
/* Create our stack frame + pt_regs */
|
|
stdu r1, -SWITCH_FRAME_SIZE(r1)
|
|
|
|
/* Save all gprs to pt_regs */
|
|
SAVE_8GPRS(3, r1)
|
|
|
|
lbz r3, PACA_FTRACE_ENABLED(r13)
|
|
cmpdi r3, 0
|
|
beq ftrace_no_trace
|
|
|
|
/* Get the _mcount() call site out of LR */
|
|
mflr r7
|
|
std r7, _NIP(r1)
|
|
std r7, LRSAVE+SWITCH_FRAME_SIZE(r1)
|
|
|
|
/* Save callee's TOC in the ABI compliant location */
|
|
std r2, 24(r1)
|
|
ld r2, PACATOC(r13) /* get kernel TOC in r2 */
|
|
|
|
addis r3, r2, function_trace_op@toc@ha
|
|
addi r3, r3, function_trace_op@toc@l
|
|
ld r5, 0(r3)
|
|
|
|
/* Calculate ip from nip-4 into r3 for call below */
|
|
subi r3, r7, MCOUNT_INSN_SIZE
|
|
|
|
/* Put the original return address in r4 as parent_ip */
|
|
mr r4, r0
|
|
|
|
/* Set pt_regs to NULL */
|
|
li r6, 0
|
|
|
|
/* ftrace_call(r3, r4, r5, r6) */
|
|
.globl ftrace_call
|
|
ftrace_call:
|
|
bl ftrace_stub
|
|
nop
|
|
|
|
ld r3, _NIP(r1)
|
|
mtctr r3
|
|
|
|
/* Restore gprs */
|
|
REST_8GPRS(3,r1)
|
|
|
|
/* Restore callee's TOC */
|
|
ld r2, 24(r1)
|
|
|
|
/* Pop our stack frame */
|
|
addi r1, r1, SWITCH_FRAME_SIZE+STACK_FRAME_MIN_SIZE
|
|
|
|
/* Reload original LR */
|
|
ld r0, LRSAVE(r1)
|
|
mtlr r0
|
|
|
|
/* Handle function_graph or go back */
|
|
b ftrace_caller_common
|
|
|
|
#ifdef CONFIG_LIVEPATCH
|
|
/*
|
|
* This function runs in the mcount context, between two functions. As
|
|
* such it can only clobber registers which are volatile and used in
|
|
* function linkage.
|
|
*
|
|
* We get here when a function A, calls another function B, but B has
|
|
* been live patched with a new function C.
|
|
*
|
|
* On entry:
|
|
* - we have no stack frame and can not allocate one
|
|
* - LR points back to the original caller (in A)
|
|
* - CTR holds the new NIP in C
|
|
* - r0, r11 & r12 are free
|
|
*/
|
|
livepatch_handler:
|
|
ld r12, PACA_THREAD_INFO(r13)
|
|
|
|
/* Allocate 3 x 8 bytes */
|
|
ld r11, TI_livepatch_sp(r12)
|
|
addi r11, r11, 24
|
|
std r11, TI_livepatch_sp(r12)
|
|
|
|
/* Save toc & real LR on livepatch stack */
|
|
std r2, -24(r11)
|
|
mflr r12
|
|
std r12, -16(r11)
|
|
|
|
/* Store stack end marker */
|
|
lis r12, STACK_END_MAGIC@h
|
|
ori r12, r12, STACK_END_MAGIC@l
|
|
std r12, -8(r11)
|
|
|
|
/* Put ctr in r12 for global entry and branch there */
|
|
mfctr r12
|
|
bctrl
|
|
|
|
/*
|
|
* Now we are returning from the patched function to the original
|
|
* caller A. We are free to use r11, r12 and we can use r2 until we
|
|
* restore it.
|
|
*/
|
|
|
|
ld r12, PACA_THREAD_INFO(r13)
|
|
|
|
ld r11, TI_livepatch_sp(r12)
|
|
|
|
/* Check stack marker hasn't been trashed */
|
|
lis r2, STACK_END_MAGIC@h
|
|
ori r2, r2, STACK_END_MAGIC@l
|
|
ld r12, -8(r11)
|
|
1: tdne r12, r2
|
|
EMIT_BUG_ENTRY 1b, __FILE__, __LINE__ - 1, 0
|
|
|
|
/* Restore LR & toc from livepatch stack */
|
|
ld r12, -16(r11)
|
|
mtlr r12
|
|
ld r2, -24(r11)
|
|
|
|
/* Pop livepatch stack frame */
|
|
ld r12, PACA_THREAD_INFO(r13)
|
|
subi r11, r11, 24
|
|
std r11, TI_livepatch_sp(r12)
|
|
|
|
/* Return to original caller of live patched function */
|
|
blr
|
|
#endif /* CONFIG_LIVEPATCH */
|
|
|
|
#ifdef CONFIG_FUNCTION_GRAPH_TRACER
|
|
_GLOBAL(ftrace_graph_caller)
|
|
stdu r1, -112(r1)
|
|
/* with -mprofile-kernel, parameter regs are still alive at _mcount */
|
|
std r10, 104(r1)
|
|
std r9, 96(r1)
|
|
std r8, 88(r1)
|
|
std r7, 80(r1)
|
|
std r6, 72(r1)
|
|
std r5, 64(r1)
|
|
std r4, 56(r1)
|
|
std r3, 48(r1)
|
|
|
|
/* Save callee's TOC in the ABI compliant location */
|
|
std r2, 24(r1)
|
|
ld r2, PACATOC(r13) /* get kernel TOC in r2 */
|
|
|
|
addi r5, r1, 112
|
|
mfctr r4 /* ftrace_caller has moved local addr here */
|
|
std r4, 40(r1)
|
|
mflr r3 /* ftrace_caller has restored LR from stack */
|
|
subi r4, r4, MCOUNT_INSN_SIZE
|
|
|
|
bl prepare_ftrace_return
|
|
nop
|
|
|
|
/*
|
|
* prepare_ftrace_return gives us the address we divert to.
|
|
* Change the LR to this.
|
|
*/
|
|
mtlr r3
|
|
|
|
ld r0, 40(r1)
|
|
mtctr r0
|
|
ld r10, 104(r1)
|
|
ld r9, 96(r1)
|
|
ld r8, 88(r1)
|
|
ld r7, 80(r1)
|
|
ld r6, 72(r1)
|
|
ld r5, 64(r1)
|
|
ld r4, 56(r1)
|
|
ld r3, 48(r1)
|
|
|
|
/* Restore callee's TOC */
|
|
ld r2, 24(r1)
|
|
|
|
addi r1, r1, 112
|
|
mflr r0
|
|
std r0, LRSAVE(r1)
|
|
bctr
|
|
#endif /* CONFIG_FUNCTION_GRAPH_TRACER */
|